About SPICE | SPICE Basics | Running SPICE | CIRCUIT COLLECTION | SPICE Commands | SPICE Demos and Downloads
About Us | Contact Us | Home | Search
 

NOISE ANALYSIS - RESISTOR EXAMPLE

CIRCUIT

                             RES_NOISE.CR                Download the SPICE file

You can't figure it out. You've taken one hundred samples of a 2.5V reference using a 16-bit ADC, but rarely are two consecutive readings the same. Okay, it's got to be noise, but where is it coming from? Unfortunately, one of our basic building blocks - the resistor - comes with its own inherent noise generator. But once we understand a little about the nature of this noise source, we have a few choices regarding how to reduce it.

RESISTOR NOISE

NOISE VOLTAGE
How is resistor noise modeled? Typically as a noise voltage in series with the resistor.

The good news is that it's predictable! And its voltage level depends on three conditions: resistor value, circuit bandwidth and temperature. So you might expect the equation predicting the RMS level to include all three

E = ( 4 k T R Δf )^½       (V RMS)

where  

            E  = the Root-Mean-Square or RMS voltage level
            k  = Boltzmans constant (1.38∙10^-23)
            T  = temperature in Kelvin (Room temp = 27 °C = 300 K)
            R  = resistance
            Δf = Circuit bandwidth in Hz (Assumes a perfect brickwall filter)

This noise is called "thermal noise." Why? It describes the random motion of thermally excited  electrons in a conductor. As an example, that 100 kΩ resistor you just stuck in your data acquisition circuit (1MHz bandwidth) will add noise to the tune of

E  = ( 4 ∙ 1.38∙10^-23 ∙ 300 ∙ 100k ∙ 1M  ) ^½
    = 40.7 μV RMS

Although it doesn't seem like much, you've just lost 1 LSB in a 18-bit ADC (+10V full scale). And if this resistor appears before a gain stage, then things can only get worse!

NOISE POWER
The noise power, or Mean-Square noise, is simply the noise voltage squared.

P = E² = 4 k T R Δf        (V²)

Why is this useful? You can add the contributions of multiple noises by adding their powers, not RMS values, as we'll see below.

NOISE SPECTRAL DENSITY

POWER SPECTRAL DENSITY
So what does noise look like across the frequency domain? Let's measure its power in a 1 Hz bandwidth at various frequencies. We would find the resistor's noise power in a 1 Hz bandwidth to be

  S = P  / Δf 
     = E² / Δf 
     =  4 k T R     (V²/Hz) 

This is called the Power Spectral Density. But at which frequency is this unit bandwidth (Δf = 1 Hz) located? Is it measured from 1 to 2 Hz, 1000 to 1001 Hz or 1,000,000 to 1,000,001 Hz? The answer is yes - any one of them! The power spectrum is equal at all frequencies.

You've heard it before, this is a White Noise spectrum. Its similar to white light containing colors at all frequencies. You can imagine the thermal noise being generated by uncorrelated sinewave generators at all frequencies.

VOLTAGE SPECTRAL DENSITY
The Voltage Spectral Density is simply the square root of the power spectral density.

    N = S ^½  
       = E / Δf ^½  
       =  ( 4 k T R )^½          (V / Hz^½)

Many manufacturers will specify the noise of their components (opamps for example) using these units.

RESISTOR NOISE EXAMPLE

Getting back to our 100 kΩ resistor, let's find its power spectral density

S = 4 k T R
   =  4 ∙1.38∙10^-23 ∙ 300 ∙ 100k
   = 1.66∙10^-15       ( V² / Hz )

and voltage spectral density

 N = S ^½
       = (4 k T R) ^½
       = 40.7 ∙10^-9       ( V / Hz^½ )

RMS VOLTAGE FROM SPECTRAL DENSITY

So now we ask: what is the total resistor noise for a given bandwidth such as Δf = 10,000 Hz, for example? From the power density, we easily find the total power across the bandwidth as 

P = S ∙ Δf
   = 1.66 ∙10^-15  (V² / Hz)   ∙ 10000  (Hz)
   = 16.6 ∙10^-12   (V²)

which scales with the bandwidth. We can also find the RMS voltage as

E = N ∙ Δf ^½
   = 40.7 ∙10^-9  (V/Hz^½)   ∙ (10000)^½  (Hz^½)
   = 4.07 ∙10^-6  (V)

which scales with the square-root of the bandwidth. How noisy does the 100 kΩ resistor get at other circuit bandwidths?

What is this table telling us about low-noise design? If you want a quiet circuit, then reduce bandwidth, resistor value or both!

CIRCUIT NOISE

How much noise will various resistors contribute at the output of your circuit? Four easy steps gets you the answer.

1. Calculate the voltage spectral density from each resistor noise generator.

S = 4 k T R

2. Find the voltage gain (A) from the noise generator to the output. Then
    calculate the power spectral density at the output.

So = S ∙ A²

3. Repeat 1 and 2 for all resistors.

4. Calculate the total power spectral density by adding the individual output powers directly.

S_TOT = S₁ + S₂ + S₃ + ....

    For noise voltages, you accomplish the same by square root of the
    the sum of the squares.

N_TOT = ( N₁²  + N₂²  + N₃²  + ....) ^½
 

Let's walk through an example. Our circuit above is a simple resistor divider (Gain = 1/2) followed by an amplifier (Gain = 1) and a low-pass filter (fc = 1MHz). Let's assume we're seeking the noise density at low frequencies where the low-pass filter has no effect.

Step 1: Calculate S, the power spectral density from R1.

S = 4 k T R
   = 1.66∙10^-15       ( V² / Hz )

Step 2: Find A, the voltage gain from the noise source to the output

A = R2/(R1+R2) = 1/2

then calculate the output power spectral density from R1.

So = S ∙ A²
     = 1.66∙10^-15  ∙ (1/2)²
     =  4.14 ∙10^-16    (V² / Hz)

Step 3. Repeat for all noise sources. For R2, we get the same answer as R1

So = S ∙ A²
     = 1.66∙10^-15  ∙ (1/2)²
     =  4.14 ∙10^-16    (V² / Hz)

For RLP1, we get

So = S ∙ A²
     = 1.66∙10^-18  ∙ 1
     = 1.66∙10^-18    (V² / Hz)

Step 4: Adding the contributions from all resistors we get a total power spectral density of

S_TOT = 4.14 ∙10^-16  +  4.14 ∙10^-16  + 1.66∙10^-18  
          = 8.30 ∙10^-16    (V² / Hz)

and a total voltage spectral density of

N_TOT = S_TOT ^½
       = ( 8.30 ∙10^-16  ) ^½
       =  2.88 ∙10^-8       ( V / Hz^½ )

There you have it! At low frequencies, your resistors contribute a total of 28.8 nV/ Hz^½ at the circuit's output.
 

WARNING!!! In this simple example, the gain (A) was found at low frequencies where the gain was flat. However, at higher frequencies, the low-pass filter rolls off the response. Real circuits include filters and amplifiers with gains that vary with frequency. Consequently, you need to calculate the output power spectral densities across the frequency range of your circuit! Sound fascinating? Yes! Sound like a pain in the can? Yes, again! Luckily, SPICE is equipped with the power tools you need.

SPICE NOISE ANALYSIS

What can SPICE do regarding noise analysis? SPICE essentially performs the 4 steps outlined above for you. For example, the statement

.NOISE V(4) V1  5

asks SPICE for the following.

1. Calculate the power spectral density from every resistor to the output node V(4). This
    is performed at every 5th frequency point specified in the AC analysis.

2. Find the total power spectral density and total voltage spectral density at node 4.

3. Calculate the transfer function V(4) / V1 to determine the total noise referred to the
    input source V1.

 CIRCUIT INSIGHT   Simulate the SPICE file RES_NOISE.CIR. To recap, this circuit implements a simple resistor divider (Gain = 1/2) followed by an amplifier (Gain = 1) with a low-pass filter (fc = 1MHz).

Open the output file RES_NOISE.OUT to view the noise results. For every 5 th frequency of the AC analysis (100, 1000, 10000, ... Hz), SPICE prints out a nice noise summary. At 100 Hz for example, we see the power spectral density from each resistor R1, R2 and RLP1. Do the results match the densities calculated above? How about the total power and voltage spectral density, does it match our numbers above?

Seeing the noise from every resistor gives you some incredible insight! Why? It tells you who are the major contributors! Knowing the biggest noise makers, you can plan some noise reduction strategies - typically reducing bandwidth or resistor values.
 

 HANDS-ON DESIGN    Try lowering the resistors to values like R1 = R2 = 1 kΩ. What is the effect on total noise? Increase the gain of amplifier in the EAMP statement. How does it effect noise?

What have you noticed about the noise spectral density at high frequency? The noise begins to drop thanks to the low-pass filter RLP1 and CLP1. This could be a good thing! But of course, here's another one of life's balancing acts. Small bandwidth is good for low-noise, but not if it cuts into your signal's bandwidth!

 Cool Feature    SPICE let's you plot the total voltage spectral density at the output V(4) or the input V1. Just add trace ONOISE or INOISE to the plot window. You can even add these variables to a .PRINT statement!

RMS VOLTAGE CALCULATION

Let's revisit calculating the RMS voltage from the power and voltage spectral densities. Here are some possibilities.

METHOD 1:  FLAT SPECTRAL DENSITY AND A BRICKWALL FILTER
Given a flat noise density and a brickwall filter Δf, you can find the power by

P = S ∙ Δf        (V²)

and the RMS voltage from

E = N ∙ Δf ^½     ( V )

Unfortunately, life rarely hands you a flat density or a brickwall filter.

METHOD 2:  FLAT SPECTRAL DENSITY AND A SIMPLE LOW PASS FILTER
A low-pass filter is similar to a brickwall filter. But, because it's response falls off slowly in the stop band, it passes more high frequency noise than a brickwall filter. How much more noise? The single-pole low-pass filter allows 1.5 times more noise power than a brickwall filter. Given the low-pass cutoff frequency fc, you can find the power

P = S ∙ ( 1.5 ∙ fc )        (V²)

and the RMS voltage

E = N ∙ ( 1.5 ∙ fc ) ^½     ( V )

You could say, for a flat power spectral density, the low-pass filter has an equivalent noise bandwidth of

Δf  = 1.5 ∙ fc

METHOD 3:  A VARYING SPECTRAL DENSITY VERSUS FREQUENCY
Suppose you don't have a flat output noise spectral density. Your amplifiers and filters create a spectral density that varies significantly versus frequency. In this case you can integrate S across the frequency range to get the total power

P = ∫ S(f) df       (V²)

and the RMS voltage

E = (  ∫ N(f)² df  ) ^½     ( V )

Unfortunately, many times we don't have nice neat equations for output noise. Instead, we have spectral densities calculated at discrete frequency points, (f_n = f₁, f₂, f₃, ...), like SPICE's noise analysis. In this case, we can approximate the integral by summing the noise in a number of bandwidths Δf_n = f_n+1 -  f_n across the frequency range.

P = ∑ S_n ∙ Δf_n      (V²)

E = ( ∑ N_n² ∙ Δf_n) ^½     ( V )

 Cool Feature    You can easily implement this last equation in many SPICE simulators. Recalling that ONOISE represents the voltage spectral density, v, simply add the following equation to the plot window.

SQRT(SUM(ONOISE*ONOISE))

The far right of the graph shows the total RMS voltage of your circuit. This can be handy for calculating the SNR of your design. (NOTE: You might have noticed that the frequency Δf_n is absent from the equation above. Actually, the SUM function automatically includes the Δf_n term.)

 CIRCUIT INSIGHT   Simulate the SPICE file RES_NOISE.CIR with an EAMP gain =1, R1 = R2 = 100k, RLP1 = 100 and CLP1 = 1.59 nF. This time add the trace ONOISE to a plot window. Now, open a new plot window and add the trace SQRT(SUM(ONOISE*ONOISE)). What is the total RMS noise voltage at the highest frequency point of the graph?

Can we get the same answer by Method 2 above assuming a flat noise density and a simple low-pass filter? From the plot of ONOISE, find the voltage spectral density of the resistors

N = 28.8 nV / Hz^½

Next, knowing the cutoff frequency fc of the low-pass filter, determine the total RMS output noise.

E = N ∙ ( 1.5 ∙ fc ) ^½  
    = 28.8  nV / Hz^½  ∙ ( 1.5 ∙ 1 MHz) ^½
    = 35.2 μV RMS

Is this result close to RMS level found using the SUM function?

SNR

Now, what is your system's Signal-to-Noise Ratio (SNR) given a signal strength of 10 mV RMS?

SNR = Vsig / E
         = 10 mV / 35.2 μV
         = 284   (49 dB)

 HANDS-ON DESIGN   Suppose this SNR is not good enough! How much can you lower the bandwidth to get an SNR = 500? What about lowering R1 and R2? But watch out! If you're designing a battery-powered device, low resistor values may sap away precious energy.

FINAL NOTE

Noise can be one of the more challenging and tougher design topics! Sometimes it takes a few trips around the block before it begins to make sense. Here are some helpful guides.

SPICE, A Guide to Circuit Simulation and Analysis Using PSPICE, P. Tuinenga, Prentice-Hall.

Low-Noise Electronic System Design, C. Motchenbacher and J. Connelly, John-Wiley and Sons, 1993.

Analysis and Design of Integrated Circuits, P. Gray and R. Meyer, John-Wiley and Sons, 1993.

SPICE FILE

Download the file or copy this netlist into a text file with the *.cir extension.

RES_NOISE.CIR - NOISE ANALYSIS: RESISTOR DIVIDER, AMP, AND LP FILTER
*
* RESISTOR DIVIDER
V1	1	0	AC	1	DC	5
R1	1	2	100K
R2	2	0	100K
*
* AMP AND LP FILTER
EAMP	3 0	2 0 1
RLP1	3	4	100
CLP1	4	0	1.59NF
* 
.AC 	DEC 	5 100 100MEG
.NOISE	V(4)	V1	5
.PRINT NOISE ONOISE
.PROBE
.END

Top ↑

© 2005 eCircuit Center