eCircuit  Center

 


About SPICE | SPICE Basics | Running SPICE | CIRCUIT COLLECTION | SPICE Commands | SPICE Demos and Downloads
About Us | Contact Us | Home | Search
 

 

H-Bridge Power Amp

CIRCUIT

 

           HBRIDGE POWER AMP.CIR                Download the SPICE file

Suppose you're asked to design a power amplifier with two performance goals: 1) create a 10V peak-to-peak voltage swing and 2) drive both positive and negative polarities. A bipolar output can be handy if you need to drive a motor in both directions.

The problem is that you're restricted to single 5V supply! Mostly we're stuck in thinking we'll drive one end of a load (speaker, motor, etc.) while keeping the other end anchored at ground. But, why not lift the grounded end and drive it too? Sure, the circuit's complexity increases, but the benefits may be worth it - twice the voltage swing and bipolar drive.

 

H-BRIDGE

So what's with the name: h-bridge? I don't see anything resembling that letter. But let's look at the op amp's push-pull output transistors ( Q1,Q2 from XOP1 and Q3,Q4 from XOP2 ) together with the load.

And therein lies its beauty and namesake. If you need current to flow in the direction indicated, turn on Q1 and Q4. For current to flow in the opposite direction, turn on Q2 and Q3 along the opposite diagonal.

 

MASTER / SLAVE

Two amplifiers make up this circuit team: a master XOP1 and a slave XOP2. Basically, the master can be anything - inverting or non-inverting, gain or attenuation - whatever is necessary. The circuit above is configured as an inverting amplifier.

The slave, on the other hand, has one purpose in life - a unity gain inverting amplifier. It's job is to deliver the same magnitude, but opposite polarity, to the load.

 

POWER AMPLIFIER

The resistors for both master XOP1 and slave XOP2 are initially chosen for a gain of -1. In addition, suppose the circuit is powered by a single +5V supply. Voltage VREF simply provides a reference midway between the supply rails at +2.5V. What generates this voltage? In a real circuit, you can string a voltage divider across the 5V supply and buffer it with a unity gain op amp. Or, if you expect a lot of current to flow in or out of VREF, a voltage regulator will do the job nicely. For the amplifier's input signal, VS generates a 5 V p-p 1 kHz sinewave .

 CIRCUIT INSIGHT   Run a simulation of HBRIDGE POWER AMP.CIR. Take a look at both outputs V(4) and V(7). If all went well, you should see two 5 Vp-p signals with opposite polarity. But the real payoff is the signal the load sees. Plot the difference between output voltages (the voltage across the load) by adding trace V(4,7) or V(4)-V(7). From a single 5 V supply, the load receives a 10 Vp-p bipolar signal!

 HANDS-ON DESIGN    If gain is needed, you can configure the master amp to provide it. Boost the gain to 10 or 100 by adjusting the R2 / R1 ratio. Accordingly, reduce the peak input voltage in the SIN function of VS. Alternatively, if you wish, change the master amplifier to a non-inverting configuration. If you have the luxury of dual supplies like ± 5V, change the amplifier to a bipolar one by setting VREF to 0V or removing it altogether.

 

POWER OP AMP

The above discussion assumes the op amp used can actually deliver the required current and dissipate the expected power. Several op amps on the market are specifically designed for this purpose - el grande currents and voltages - all implemented with the proper heatsinking of course. If one is not available, you can always strap a discrete push-pull transistor pair at the op amp's output inside the feedback loop (See the Push-Pull Output topic.)

A couple of nice bonus features come with the H-bridge package. You get twice the slew-rate as the individual op amp and second-order harmonics cancel out at the load.

 

SPICE FILE

Download the file or copy this netlist into a text file with the *.cir extension.

HBRIDGE_POWER_AMP.CIR - SINGLE-SUPPLY H-BRIDGE CIRCUIT
*
* INPUT VOLTAGE
VS	1	3	DC	0	SIN(0VOFF  2.5VPEAK  1.0KHZ)
*
* SINGLE SUPPLY REFERENCE VOLTAGE
VREF	3	0	DC	2.5V
*
R1	1	2	10K
R2	2	4	10K
XOP1	3 2	4	OPAMP1	
*
RL	4	7	10
*
R3	4	5	10K
R4	5	7	10K
XOP2	3 5	7	OPAMP1
*
*
* OPAMP MACRO MODEL, SINGLE-POLE
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN	1	2	10MEG
* GAIN BW PRODUCT = 10MHZ = DCGAIN x POLE1
* DC GAIN (100K) AND POLE 1 (100HZ)
EGAIN	3 0	1 2	100K
RP1	3	4	1K
CP1	4	0	1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EOUT	5 0	4 0	1
ROUT	5	6	10
.ENDS
*
* ANALYSIS
.TRAN 	0.01MS  	2.0MS
*
* VIEW RESULTS
.PRINT	TRAN V(4) V(7) V(4,7)
.PROBE
.END

 

Top ↑

© 2003 eCircuit Center