About SPICE | SPICE Basics | Running SPICE | CIRCUIT COLLECTION | SPICE Commands | SPICE Demos and Downloads
About Us | Contact Us | Home
 

Op Amp Bandwidth

CIRCUIT

                             OP_BANDWIDTH1.CIR                Download the SPICE file

Its all about speed - at least that's what this topic is about. In an ideal world, an op amp responds accurately and instantly to an audio or video signal. But in the real world, there's a limit on the highest frequency (bandwidth) and fasted edge your op amp can process. A few simple concepts provide insight into an amplifier's bandwidth. And knowing this can help you make better op amp and circuit choices.

THE REAL STORY OF GAIN

To understand bandwidth, we must understand the real gain equation. You've probably seen the ideal Closed-Loop voltage gain equation for a non-inverting amplifier.

But, what's the real story including the op amp's internal gain? It actually looks like this

where A  - open-loop gain - internal gain of the op amp itself.
                                           

β   - feedback factor - how much of the output is fed back to the negative input
                                  

Here's the beauty of this equation. Check out what happens to GCL if A is made large.

For A >> (R2+R1) / R1,              

The bottom line? The gain is set by R1 and R2, not the op amp gain A! ( This fact certainly simplifies op amp circuit design.) And consequently, A can vary due to initial tolerances or temperature drift, but the voltage gain holds rock solid set by the resistor values!

BANDWIDTH

So what's the problem with the real gain equation? Although, A is large at lower frequencies, it falls at higher frequencies. And when A drops near (R2+R1) / R1, GCL drops too. The frequency where GCL falls below the ideal gain is called the bandwidth fc.

 CIRCUIT INSIGHT   Run a simulation of OP_BANDWIDTH1.CIR. The closed-loop gain for this circuit is GCL = (10k+10k)/10k = 2 V/ V. Plot the AC Response for the output at V(4) and A via the equation V(4)/(V(2)-V(1)). To get a clearer view, select log for the Y-Axis. For this particular op amp, A has a DC gain of 100,000 V/V, then falls off above 100 Hz. What about GCL? You can see that all is well as long as A >> 2. But when A drops close to GCL, the closed-loop gain takes a dive.

Note where GCL begins to drop. The frequency where the voltage falls to 0.707 of its intended value is the cutoff or -3 dB frequency, fc. ( Gain in decibels = 20∙log(0.707) = -3dB. )

 HANDS-ON DESIGN   Pick a higher gain for this amplifier. Choose R2 somewhere in the range of 10 k to 10,000 kΩ. Rerun the simulation. Yes, GCL looks great at low frequencies, but what happened to the bandwidth? Because GCL is essentially bounded by A, the bandwidth fc gets smaller as gain increases! Life and circuit design are full of compromise, and gain versus bandwidth is a fine example.

Let's try to extend the bandwidth. To do this, provide the op amp with more available A by increasing its DC gain or bandwidth. The op amp model simulates the DC gain with EGAIN 3 0 1 2 100K. Increase the 100k by a factor of 10 or so. Or, you can increase the bandwidth by decreasing RP1 or CP1 by a factor of 10. Run a new simulation. Did your new op amp extend the bandwidth at V(4)?

GAIN-BANDWIDTH PRODUCT

As you have seen, gain and bandwidth have a relationship. More precisely, the product of closed-loop gain GCL and bandwidth fc is constant!

                     Gain x Bandwidth = GCL x fc = GBP (Gain Bandwidth Product)  

What does this mean? If you want to increase the gain GCL, the bandwidth fc will drop to maintain a constant GBP. Alternatively, if you need a higher bandwidth, then lower the gain. If you need both higher gain and bandwidth, pick an op amp with a higher GBP on its data sheet. (GBP may be also called the Unity-Gain Frequency.)

You can use GBP to predict the bandwidth at any gain. For example, a non-inverting amplifier having a GBP = 10 MHz and R1 = R2 = 10k gives a closed-loop gain GCL = 2 and a bandwidth of

fc =     GBP   /  GCL
    =  10 MHz /  2
    = 5 MHz
 

 HANDS-ON DESIGN   Run a few simulations with various voltage gains of OP_BANDWIDTH1.CIR. Plot the AC Response at the output at V(4) and A via the equation V(4)/(V(2)-V(1)). You should be able to predict the bandwidth at V(4) for any of your chosen gains.

THE INVERTING AMPLIFIER

What about the other major player in op amp circuits: the inverting amplifier? The results are similar with a slight twist. Let's start with the closed-loop gain equation

where A is the internal gain. The feedback factor is

β = R1 / (R1+R2).

Note, the feedback factor, β = R1 / (R1+R2), is the same for inverting or non-inverting amplifier. That's because β is calculated with VS set to 0V, making both circuits look the same!

Similar to the non-inverting amplifier, when A is large, the ideal inverting gain is achieved.

     For A >> (R2+R1) / R1,              

However, as A drops close to the ideal gain, the actual GCL begins to drop. How do we predict this frequency where the gain falls off? Using GBP we calculate

fc = GBP /  GN

But here's the twist, the fc calculation uses the non-inverting gain

GN = (R1 + R2) / R1

in the denominator, not the inverting gain! For example, an op amp having a GBP = 10 MHz and R1 = R2 = 10k gives an inverting gain of GCL = -1. However, the bandwidth is reduced by
GN = (R1 + R2) / R1 = 2 giving

fc =     GBP   /  GN
    =  10 MHz /  2  
    =  5 MHz

There's the disadvantage of the inverting amplifier: signals are amplified by the R2 / R1 ratio, but the bandwidth is knocked down by the larger ( R1+R2 ) / R1 ratio.

( GN is also called the noise gain because op amp input errors and noise are amplified by the non-inverting gain, even for the inverting amplifier. )

 CIRCUIT INSIGHT   Try out the inverting amplifier in the OP_BANDWIDTH1.CIR. Plot the AC Response for the output V(14) and the op amp's internal gain V(14)/V(12). A log plot on the Y-Axis can give a better view. The gain should match the ideal -R2 / R1 as long as A is larger than (R1+R2)/R1.

 HANDS-ON DESIGN   Crank up the gain by choosing R2 somewhere in the range of 10 k to 10,000 kΩ. Rerun the simulation. For any gain, GCL should be bounded by A. Does the bandwidth get smaller as you increase gain?

NON-INVERTING VS. INVERTING AMPLIFIER

Here's a showdown between the two classic amplifiers. The challenge is this: for the same gain, which amplifier has the greater bandwidth? We'll use a voltage gain of 2 for both circuits.

The bandwidth champion is the non-inverting amplifier! However, this bandwidth difference is less for larger gains. Still, all other things being equal, choose the non-inverting amplifier to maximize your bandwidth.

 CIRCUIT INSIGHT   Run a simulation of OP_BANDWIDTH1.CIR. Set the resistors in the non-inverting and inverting amplifiers to values in the table above. Plot the AC output at V(4) and V(14). Did the non-inverting gain live up to expectations?

Another way to measure circuit speed is how fast the amplifier responds to a step input. In the real world, the step input represents a quick brightness change in a video signal or the rising / falling edge of a clock signal. Run a simulation and plot the Transient Response at V(4) and V(14). How much faster does the non-inverting output reach 90% of its final value compared to the inverting output?

MORE TO BANDWIDTH

Although GBP and gain play a major role in determining bandwidth, there's more to it. Slew rate and heavy loading can cut into your bandwidth. Slew rate would not only make an interesting design topic, but a challenging simulation topic as well. Its on the list of future topics. Let us know which design topics or circuits peak your interest.

SIMULATION NOTES

For a more detailed description of the op amp, see the Basic Op Amp Model.
For a quick review of subcircuits, check out Why Use Subcircuits?

SPICE FILE

Download the file or copy this netlist into a text file with the *.cir extension.

OP_BANDWIDTH1.CIR - OPAMP BANDWIDTH
*
VS	1	0	AC 1V	PWL(0US 0V   0.01US 1V  100US 1V)
*
*
* NON-INVERTING AMPLIFIER
R1	2	0	10K
R2	2	4	10K
XOP1	1 2	4	OPAMP1
*
* INVERTING AMPLIFIER
R_1	1	12	10K
R_2	12	14	10K
XOP2	0 12	14	OPAMP1	
*
*
* OPAMP MACRO MODEL, SINGLE-POLE 
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN	1	2	10MEG
* DCGAIN =100K AND POLE1=1/(2*PI*RP1*CP1)=100HZ
* GBP = DCGAIN X POLE1 = 10MHZ
EGAIN	3 0	1 2	100K
RP1	3	4	1000
CP1	4	0	1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER	5 0	4 0	1
ROUT	5	6	10
.ENDS
*
*
* ANALYSIS
.AC 	DEC 	5 10 100MEG
.TRAN 	0.01US  0.5US
*
* VIEW RESULTS
.PRINT	AC 	VM(4)
.PRINT	TRAN 	V(4) V(14)
.PROBE
.END

Top ↑

© 2003 eCircuit Center