eCircuit  Center

 


About SPICE | SPICE Basics | Running SPICE | CIRCUIT COLLECTION | SPICE Commands | SPICE Demos and Downloads
About Us | Contact Us | Home

 

 

I-to-V Amplifier
(Trans-impedance Amp)

CIRCUIT

 

                             OPITOV.CIR                Download the SPICE file

You may have noticed that most circuits work on this principle: Voltage In, Voltage Out. But, what about the sensors such as a photodiode and DACs (Digital-to-Analog Concverter) that produce a current output? Photodiodes may be called into action for applications such as precision light meters, high-speed fiber-optic receivers or X-ray detectors. Many types of DACs produce a current proportional to the digital word at it's input. These devices require you to this current to a useful voltage.

 

TRANSIMPEDANCE AMPLIFIER

The op amp current-to-voltage converter (transimpedance amplifier) is a fairly simple circuit. Two key principles clarify operation.

1. Because no current flows into the op amp itself, the current Is has nowhere to go but through the resistor RF.

2. One leg of RF is held at ground potential (0V). Why? Remember the main job of the op amp is to adjust the output such that the inverting input equals the non-inverting input. And, because the non-inverting input is at ground (0V), the inverting input - along with one end of RF - will be held at 0V.

What does it all mean? The output Vo can be described simply as the voltage across the resistor VRF.

Vo = VRF = -Is RF

 

 CIRCUIT ANALYSIS   The current source IS delivers a 10 uA pulse (20 us wide) to the transimpedance amp. The output voltage V(2) should show the same pulse scaled by RF and inverted. Run a simulation of OPITOV.CIR. Plot the Transient Response of input current I(IS) and output voltage V(2). To get a better view of the input current, you may need to display it in a separate plot window.

 HANDS-ON DESIGN   Suppose you needed a larger output voltage given the same 10 uA source? Pick a higher output voltage level and calculate a new RF. (Example: For a 2V output pulse, choose RF = 2V / 10 uA = 200k.) Test drive your circuit and check the output swing.

 

SENSOR RESISTANCE

 CIRCUIT INSIGHT   Resistor RS represents the sensors source impedance. Insert RS across IS by removing the * at the beginning of the RS statement. Run a simulation. Did the output change? Increase or decrease RS by a factor of 10 or so. Why doesn't the output change? The op amp creates a fairly low impedance at the negative input by forcing it near 0V. As a result, most of IS will flow into this low impedance; not into the relatively higher resistance of RS.

 

WARNING - INSTABILITY AHEAD

The implementation of the trans-impedance amplifier is fraught with danger. Even a small stray capacitance can make the output overshoot and ring. Check out the topic on trans-impedance amp stability.

 

SPICE FILE

Download the file or copy this netlist into a text file with the *.cir extention.

OPITOV.CIR - CURRENT-TO-VOLTAGE CONVERTER (TRANSIMPEDANCE AMP)
*
* SENSOR
IS	0	1	AC 1 PWL(0US 0UA  1US 10UA  20US 10UA  21US 0  40US 0)
*RS	1	0	500K
*CS	1	0	100PF
*
* TRANSIMPEDANCE AMPLIFIER
RF	1	2	100K
*CF	1	2	2PF
XOP1	0 1	2	OPAMP1
*
* OPAMP MACRO MODEL, SINGLE-POLE 
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN	1	2	10MEG
* gain bandwidth product = DCGAIN x POLE1 = 10MHZ
* DCGAIN=100K AND POLE1=100HZ
EGAIN	3 0	1 2	100K
R1	3	4	1K
C1	4	0	1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER	5 0	4 0	1
ROUT	5	6	10
.ENDS
* 
* ANALYSIS
.TRAN 	0.2US  	40US
.AC 	DEC 	10 100 10MEG
* VIEW RESULTS
.PROBE
.END

 

top

2002-2010 eCircuit Center